GridTalk.de - Fertige Scripts

Name des Objects als Hovertext

Sat, 24 Feb 2018 17:18:12 +0100

Einen normalen Hovertext habe ich aber da muß ich bei jedem Objekt in den ich ihn packe immer den Text im Script ändern.

Viel besser wäre es wenn ich nur den Namen des Objectes ändern müßte und der Hovertext gibt diesen Namen an.

Perfekt wäre es, wenn der Namen nicht dauernd über der Kiste steht, sondern nur bei mouseover erscheint.

Weiß jemand Rat?

1000 Scripts - Repo

Mon, 24 Aug 2015 11:24:13 +0200

Hallo zusammen ;D

Hab per Zufall ein Repo bei Github gefunden, was 1000 LSL Scripts beinhaltet. Diese Scripts gehören zu der Seite OutWorldz.com, dahinter steckt nun widerrum ein Hardware Hersteller.

Hier der Link zu der Repo
https://github.com/Ferdzee/LSL-Scripts

Viel Spass beim testen ;D

Mirrorscript von Aine Caoimhe

Thu, 23 Jul 2015 21:20:01 +0200

Hier ein schönes Mirror Script, wurde von Spike gefunden, werde es mal hier unterbringen, da es im Blog von der Aime ein bisschen unglücklich eingebunden wurrde.

Code:
// Mirror script

// by Aine Caoimhe (c. LACM) July 2015

// Provided under Creative Commons Attribution-Non-Commercial-ShareAlike 4.0 International license.

// Please be sure you read and adhere to the terms of this license: https://creativecommons.org/licenses/by-nc-sa/4.0/

//

// When an avatar sits on an object containing this script the avi will be cloned to an NPC who will also sit

// Paired aniamtions supplied in the object will be played, making it appear as though the NPC is the mirrored user

// If the sitter touches the mirror it will advance to the next pose (if there are more to play)

// when the sitter stands, the NPC is removed

// (Note: if sitter changes appearance during use the NPC will not change to copy that change...it will continue to appear as intiailly rezzed)

//

// Place this script in the ROOT prim which can either be the mirror object itself or ain invisible prim placed at that location.

// It is assumed that the root prim's XZ-plane is the axis to be mirrored

//

// Add animations to the contents of the root prim in pairs where each pair consists of:

//      - an animation for the sitter to play

//      - an animation that mirrors this, that has the IDENTICAL NAME with " mirror" (including the leading space) added after it

//      example: "sit 1" and "sit 1 mirror"

// DO NOT have a main sitter pose end with the word mirror because it would be interpretted as being a mirror pose and ignored

//

// ***** IF YOU ADD OR REMOVE ANIMATIONS YOU WILL NEED TO RESET THE SCRIPT TO PICK UP THE CHANGES!!! *****

//

// The sitter's pose position is determined by the base sitPos and sitRot settings (see user settings section below) UNLESS you

// overide these for an animation by placing new values in the DESCRIPTION field of the main pose in the format:

//      ::        <--- note the double colon separator between position and rotation

//                                  example:  <0.0, 1.0, 0.0>::<0.0, 0.0, 0.0, 1.0>

// at which point the sitter will be moved to that sit target posision instead

//

// In all cases, the clone (mirror NPC) will be positioned exactly 180 rotated around the root prim's LOCAL Z axis

// If you have already rotated the mirror pose animation on axis when creating the mirror and do not need it subequently rotated

// when the clone NPC plays it, set the user variable mirrorRot to FALSE, otherwise leave it TRUE (this applies to all animations played

// so you can't use a mixture of both, sorry)

//

// USER SETTINGS

// use something like the Magic Sit Kit to set the value of these two

integer sayPoseName=TRUE;                   // TURE = owner will be told the name of the pose each time one is activated, FALSE = mirror will be silent

integer userName=FALSE;                     // TRUE = NPC will have the sitter's name, FALSE = NPC will have empty name

vector sitPos=<0.0, 1.0, 0.0>;              // base sit target position to set for the main sitter relative to the mirror - NPC clone will mirror this position on the opposite side of the mirror

rotation sitRot=<0.0, 0.0, 0.0, 1.0>;       // base sit target rotation to set for the main sitter relative to the mirror - NPC clone will mirror this on the opposite side of the mirror

integer mirrorRot=TRUE;     // FALSE = the mirror animations you are supplying are already rotated on root; TRUE = they need to be rotated by the script

string baseAn="*****base__stand priority 1";    // name of a base priority 1 animation to use for underlying synch (no mirror pose of it is needed)

//

// * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *

// DO NOT CHANGE ANYTHING BELOW HERE UNLESS YOU KNOW WHAT YOU'RE DOING

// * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *

list poses;

list mirrors;

integer anIndex;

key user;

key npc;

integer linkNpc;

integer linkUser;

updatePositions()

{

    vector pos=sitPos;

    rotation rot=sitRot;

    // see if this pose requires position override

    string posOverride=osGetInventoryDesc(llList2String(poses,anIndex));

    if (llSubStringIndex(posOverride,"::")>=0)

    {

        list orData=llParseString2List(posOverride,["::"],[]);

        pos=llList2Vector(orData,0);

        rot=llList2Rot(orData,1);

    }

    vector size = llGetAgentSize(user);

    float fAdjust = ((((0.008906 * size.z) + -0.049831) * size.z) + 0.088967) * size.z;

    vector newPos=(pos + <0.0, 0.0, 0.4>) - (llRot2Up(rot) * fAdjust);

    llSetLinkPrimitiveParamsFast(linkUser, [PRIM_POS_LOCAL,newPos,PRIM_ROT_LOCAL, rot]);

    newPos.y=-newPos.y;

    if (mirrorRot)

    {

        vector aviRot=llRot2Euler(rot);

        aviRot.z=-aviRot.z;

        aviRot.x=-aviRot.x;

        rot =llEuler2Rot(aviRot);

    }

    llSetLinkPrimitiveParamsFast(linkNpc, [PRIM_POS_LOCAL,newPos,PRIM_ROT_LOCAL, rot]);

    if (sayPoseName) llOwnerSay("New pose: "+llList2String(poses,anIndex));

}

buildPoseList()

{

    list an;

    poses=[];

    mirrors=[];

    integer i=llGetInventoryNumber(INVENTORY_ANIMATION);

    while (--i>=0) { an=[]+[llGetInventoryName(INVENTORY_ANIMATION,i)]+an; }

    i=llListFindList(an,[baseAn]);

    if (i==-1)

    {

        llOwnerSay("ERROR! Unable to locate the base priototy 1 aniamtion: "+baseAn);

        user="ERROR";

    }

    else an=[]+llDeleteSubList(an,i,i);

    i=llGetListLength(an);

    while (--i>=0)

    {

        string name=llList2String(an,i);

        if (llGetSubString(name,-7,-1)!=" mirror")

        {

            integer m=llListFindList(an,[name+" mirror"]);

            if (m==-1) llOwnerSay("WARNING: found an animation with the name \""+name+"\" but no matching animation was located");

            else

            {

                poses=[]+[name]+poses;

                mirrors=[]+[name+" mirror"]+mirrors;

            }

        }

    }

    // double-check even though mismatch ought to be impossible;

    if (llGetListLength(poses)!=llGetListLength(mirrors))

    {

        llOwnerSay("ERROR! Somehow build pose and mirror lists with mismatched lengths. Dump of data:\n\nPOSES: "+llDumpList2String(poses,", ")+"\nMIRRORS: "+llDumpList2String(mirrors,", "));

        user="ERROR";

    }

    else

    {

        anIndex=0;

        if (llGetListLength(poses)==1) llOwnerSay("Pose list built. Found only 1 mirrored pose in inventory so disabling touch advance");

        else llOwnerSay("Pose list built. Found "+(string)llGetListLength(poses)+" mirrored pose in inventory");

    }

}

cleanSitters()

{

    user=NULL_KEY;

    npc=NULL_KEY;

    integer l=llGetNumberOfPrims();

    while (l>0)

    {

        key who=llGetLinkKey(l);

        if (llGetAgentSize(who)==ZERO_VECTOR) l=0; // agents are always the last link numbers

        else

        {

            if (osIsNpc(who)) osNpcRemove(who);

            else

            {

                llRegionSayTo(who,0,"Sorry, the system has been reset so you will need to sit down again");

                llUnSit(who);

            }

        }

        l--;

    }

}

default

{

    state_entry()

    {

        buildPoseList();

        llSitTarget(<0.0, 0.0, 0.000001>,ZERO_ROTATION);

        llSetClickAction(CLICK_ACTION_SIT);

        if (user=="ERROR") llOwnerSay("Cannot active device until animation list building errors are correct");

        else cleanSitters();

    }

    on_rez(integer foo)

    {

        llResetScript();

    }

    touch_start(integer num)

    {

        key who=llDetectedKey(0);

        if (who!=user)

        {

            if (user==NULL_KEY) llRegionSayTo(who,0,"Please sit on me to use me");

            else llRegionSayTo(who,0,"Sorry, only the current user can touch me");

        }

        else

        {

            if (llGetListLength(poses)==1) return;   // with only 1 pose no changing

            osAvatarStopAnimation(user,llList2String(poses,anIndex));

            osAvatarStopAnimation(npc,llList2String(mirrors,anIndex));

            anIndex++;

            if (anIndex>=llGetListLength(poses)) anIndex=0;

            osAvatarPlayAnimation(user,llList2String(poses,anIndex));

            osAvatarPlayAnimation(npc,llList2String(mirrors,anIndex));

            updatePositions();

        }

    }

    changed (integer change)

    {

        if (change & CHANGED_OWNER) llResetScript();

        if (change & CHANGED_REGION_START) llResetScript();

        if (change & CHANGED_INVENTORY) llOwnerSay("Detected a change in inventory. Remember to reset the script if you have changed the animations");

        if (change & CHANGED_LINK)

        {

            // find out who is currently sitting

            list aviSitters=[];

            list npcSitters=[];

            integer l=llGetNumberOfPrims();

            while (l>0)

            {

                key who=llGetLinkKey(l);

                if (llGetAgentSize(who)==ZERO_VECTOR) l=0;  // sitters are always last links

                else

                {

                    if (osIsNpc(who))

                    {

                        npcSitters=[]+[who]+npcSitters;

                        if (who==npc) linkNpc=l;

                    }

                    else

                    {

                        aviSitters=[]+[who]+aviSitters;

                        if (who==user) linkUser=l;

                    }

                }

                l--;

            }

            if (user==NULL_KEY)

            {

                l=llGetListLength(npcSitters);

                while (--l>=0) { osNpcRemove(llList2Key(npcSitters,l)); }

                npc=NULL_KEY;

                if (llGetListLength(aviSitters)==0)

                {

                    llSetClickAction(CLICK_ACTION_SIT); // back to sit as default action

                    return;     // link change triggered by user standing or a change in some other linkset action

                }

                // getting here means a new avi sat

                user=llList2Key(aviSitters,0);

                osAvatarPlayAnimation(user,baseAn); // initiate base an

                llSetClickAction(CLICK_ACTION_TOUCH);   // now in use so default action should be touch

                string first=" ";

                string last=" ";

                if (userName)

                {

                    string nameToParse=llList2String(llGetObjectDetails(user,[OBJECT_NAME]),0);

                    list parsedName=llParseString2List(nameToParse,[" ",".","@"],[]);

                    first=llList2String(parsedName,0);

                    last=llList2String(parsedName,1);

                }

                npc=osNpcCreate(first,last,llGetPos()+<0.0,0.0,1.0>,user);

                osAvatarPlayAnimation(npc,baseAn);

                osNpcSit(npc,llGetKey(),OS_NPC_SIT_NOW);

                // everything else handled when NPC is detected as sitting

            }

            else if (user=="ERROR")

            {

                l=llGetListLength(npcSitters);

                while (--l>=0) { osNpcRemove(llList2Key(npcSitters,l)); }

                l=llGetListLength(aviSitters);

                while (--l>=0)

                {

                    llRegionSayTo(llList2Key(aviSitters,l),0,"Sorry, the mirror has encountered an error and needs to be reset");

                    llUnSit(llList2Key(aviSitters,l));

                }

            }

            else

            {

                // we already have a user on record

                if (llListFindList(aviSitters,[user])==-1)

                {

                    // but no longer sitting so need to release animations, clear user, and remove NPC

                    if (llGetAgentSize(user)!=ZERO_VECTOR)

                    {

                        osAvatarPlayAnimation(user,"Stand");

                        osAvatarStopAnimation(user,llList2Key(poses,anIndex));

                        osAvatarStopAnimation(user,baseAn);

                    }

                    user=NULL_KEY;

                    if (osIsNpc(npc))

                    {

                        osNpcRemove(npc);

                        npc=NULL_KEY;

                    }

                    llSetClickAction(CLICK_ACTION_SIT); // back to sit as default action

                }

                // make sure someone else didn't sit down when user was set

                l=llGetListLength(aviSitters);

                while (--l>=0)

                {

                    if (llList2Key(aviSitters,l)!=user)

                    {

                        llRegionSayTo(llList2Key(aviSitters,l),0,"Sorry, the mirror is already being used by someone else");

                        llUnSit(llList2Key(aviSitters,l));

                    }

                }

                // prevent any NPC from sitting other than the current one on record

                l=llGetListLength(npcSitters);

                while (--l>=0) { if (llList2Key(npcSitters,l)!=npc) osNpcRemove(llList2Key(npcSitters,l)); }

                if ((npc!=NULL_KEY) && osIsNpc(npc))

                {

                    // most of the time we only get here if a new NPC sat after initial creation so this should trigger start of animation

                    // need to wait briefly for base an to kick in

                    llSleep(0.25);

                    // then clear any existing AO/sit animations

                    key dontStop=llGetInventoryKey(baseAn);

                    list anToStop=llGetAnimationList(user);

                    l=llGetListLength(anToStop);

                    while (--l>=0) { if (llList2Key(anToStop,l)!=dontStop) osAvatarStopAnimation(user,llList2Key(anToStop,l)); }

                    anToStop=[]+llGetAnimationList(npc);

                    l=llGetListLength(anToStop);

                    while (--l>=0) { if (llList2Key(anToStop,l)!=dontStop) osAvatarStopAnimation(npc,llList2Key(anToStop,l)); }

                    // now start the mirrored animations

                    osAvatarPlayAnimation(user,llList2String(poses,anIndex));

                    osAvatarPlayAnimation(npc,llList2String(mirrors,anIndex));

                    updatePositions();

                }

            }

        }

    }

}

Das Script steht unter Creative Commons Attribution-Non-Commercial-ShareAlike 4.0 International license. http://ainetutorials.blogspot.de/2015/07...cript.html

Lampen(u. Feuer)script u. Dämmerungsschalter

Mon, 13 Jul 2015 21:38:13 +0200

„Wenn man denkt es geht nicht mehr, kommt irgendwo ein Lichtlein her“

lichtlein.jpg (Größe: 17,19 KB / Downloads: 769)
Ich liebe ja so Lichtspielereien^^ u. da sich meine beiden kleinen Scriptchen recht gut in der Praxis bewährt haben, setze ich sie mal hier rein.

Das Lampenscript:

Code:
//****** Use this for a Region-Light Control ****

integer RegContchannel =1238;

string RegContOn ="on";

string RegContOff ="off";

// **********************************************

// Licht-Script

// MoniTill

// Lizenz: Gemeinfrei (Public domain)

vector lightcolor = <1.000, 0.757, 0.514>;    // The Color of the flame a lit. bit yellow 

integer lightObj =1;   // The Flame/Light Object in the Linkset

integer onoff=0; 

ligton()

 {

 llSetLinkPrimitiveParams(lightObj,[ PRIM_GLOW, ALL_SIDES, 0.21 ] );  

 llSetLinkPrimitiveParams(lightObj,[PRIM_FULLBRIGHT,ALL_SIDES,TRUE,PRIM_POINT_LIGHT, TRUE,  lightcolor, 1.0, 10.0, 0.75]); 

// llSetLinkAlpha(lightObj, 0.34, ALL_SIDES);    // Delete this for a normal Lamp

 onoff = 1;

 }

ligtoff()

 {

 llSetLinkPrimitiveParams(lightObj,[ PRIM_GLOW, ALL_SIDES, 0 ] );  

 llSetLinkPrimitiveParams(lightObj,[PRIM_FULLBRIGHT,ALL_SIDES,FALSE,PRIM_POINT_LIGHT, FALSE,lightcolor, 1.0, 10.0, 0.75 ]); 

 //llSetLinkAlpha(lightObj, 0.00, ALL_SIDES);    // Delete this for a normal Lamp

 onoff = 0;  

 }

default

{

    state_entry()

    {

      integer handle = llListen( RegContchannel, "", "", "" );     

    }

    touch_start(integer total_number)

    {

      if (onoff == 0)

      {

      ligton();

      }    

      else

      {

      ligtoff();

      }

    }

    listen(integer RegContchannel, string name, key id, string message)

    {

            if (message == RegContOn)  

      {

            ligton();

      }   

      if (message == RegContOff)  

      {

      ligtoff();

      }   

    }

}

Man trägt bei „integer lightObj =“ die Nummer des Objektes aus dem Linkset ein, welches das Leuchtmittel ist.
Falls das Leuchtmittel ein Feuer (wie zB bei einer Kerze) ist, einfach bei den beiden //llSetLinkAlpha .. Zeilen die Kommentarslashes entfernen, dann wird die Flamme beim abschalten unsichtbar.
Man kann die Lampe von Hand schalten und/oder über eine Regionskontrolle.

Diese kommt hier. Das ist ein Regionsweiter Dämmerungsschalter, der bei Sonnenhöhe 0.1 (Abends wenn es anfängt zu dämmern oder Morgens im Morgengrauen) die Lampen an bzw. ab schaltet. Und das geschieht nur einmal Abends u. Morgens. Wenn man sich ein Kerzchen angemacht hat, bläst einem das Teil diese nicht 5 min später wieder aus... Ist auch praktisch, wenn man am Sim Tag ein Nachtfoto machen will, dann kann man damit alle Lampen für kurze Zeit anschalten. Das Ding packt man einmal pro Region in ein Objekt. In der Gridtalk Region ist es der Nistkasten an der Birke bei der Holzbrücke. In Degol findet man das Ding im ersten Shop.

Ich habe das auch deshalb absichtlich getrennt, weil es per Timer die Höhe abfragt und somit mehr Ressourcen fordert als die Lampenscripte, die solange ruhen bis sie jemand anklickt oder eine Nachricht über ihren Kanal kommt.

Code:
// Lichtschalter   V1  

float schaltzeit = 0.1 ;

integer RegContchannel =1238;

integer onoff = 0;

default

{

   state_entry()

   {

     llSetTimerEvent(300);

   }

   timer()

   {

     vector sun = llGetSunDirection();

     if (sun.z <= schaltzeit && onoff == 0 )

     {

       llRegionSay(RegContchannel,"on");

       onoff = 1;

     }

    if (sun.z > schaltzeit && onoff == 1)

     {

       llRegionSay(RegContchannel,"off");

       onoff = 0;

     }

   }

   touch_start(integer total_number)

   {

      if (onoff == 0)

      {

       llRegionSay(RegContchannel,"on");

       onoff = 1;

      }    

      else

      {

       llRegionSay(RegContchannel,"off");

       onoff = 0;

      }

    }

}

Ein Wau Wau Script aus SL als Open Source

Sun, 19 Oct 2014 22:46:46 +0200

Hab was aufgeschnappt ;D

Ein Dog Script aus SL als Open Source, leider muss man dafür ins SL ...

Es ist einer dieser Breedable System, keine Ahnung ob er in OpenSim läuft. Auf WhiteCore Sim region läuft er ...

https://plus.google.com/u/0/103855501842...593oe2XAta

Intercom - neu

Wed, 14 May 2014 09:51:51 +0200

Auf vielfachen Wunsch eines einzelnen Herren hier mal die 3 Skripte, die für ein gridübergreifendes Chatsystem nötig sind. Als Basis diente das Intercom von Kira Komarov, leider ist das fehlerhaft so dass ichs umgeschrieben hab. Steht eigenlich alles im Skript drin, ansonsten einfach fragen :-)

EDIT: Hatte leider noch eine Zeile auskommentiert, nun ist es besser.
EDIT2: Löschen von ungültigen URLs korrigiert, leider mit minderem Erfolg. Siehe Script-Forum.

Code:
// Part of Intercom Chat Relay (1/3)

// Original Idea from Kira Komarov

// Rewritten by Rebbeka Revnik

// Funktion:

// Gibt den öffentlichen Chat von anderen URL Relays aus (nur von Avas)

// Funktioniert auch über Sim- und Grid-Grenzen

// Dazu gehören die Skripte url relay, message relay, chat plugin

// Diese müssen alle in ein Objekt, eventuell noch die access Notecard dazu

// Wie es funktioniert:

// Intercom Passwort

// 1. Denk dir ein Passwort aus oder...

// 2.1. Geh auf die Seite http://www.md5hashgenerator.com/index.php

// 2.2. Lass dir da eine Hash Summe generieren, die du als Passwort benutzt

// 3. Trage das Passwort unten bei INTERCOM_PASSWORD zwischen die Anführungsstriche ein

// 4. Nur die URL Relays mit dem gleichen Passwort können miteinander kommunizieren

//    Also kann man auch mehrere Systeme parallel betreiben, wenn sie über unterschiedliche Passwörter verfügen

// Zugang:

// 1. Erstelle eine NC namens access

// 2. Trage da die Namen ein die das URL Relay bedienen dürfen

// 3. Lege sie in das Objekt mit den Skripten

// 4. Das sollte man tun bevor die URLs eingetragen/abgerufen wurden, sonst darf man alles nochmal machen, weil dadurch das Skript zurück gesetzt wird

//    Standardmässig hat nur der Eigentümer Zugriff

// URLs:

// 1. Jedes URL Relay erhält beim Rezzen/Sim-Restart/Sim-Wechsel automatisch eine neue URL

// 2. Diese URLs müssen bei jedem URL Relay durch Anklicken und My URL abgerufen werden

// 3. Ein URL Relay (es reicht eins) erhält nun die URLs der anderen durch Anklicken und Add URL

// 4. Nach einer Weile (SYNC_TIME * Anzahl der URL Relays) bekommen diese URLs auch die anderen Relays

// 5. Das wirkt auch bei Rezzen/Sim-Restart/Sim-Wechsel, aber nicht bei Ändern/Zurücksetzen des Skripts

//    Dann muss die URL erneut aufgenommen und eingetragen werden

//    Falls es das Relay war wo alle anderen URLs eingetragen wurden, muss man Punkt 2 und 3 wiederholen

// Chat:

// 1. Das Chat Plugin nimmt den Chat auf

//    Falls es sich nicht um Objekte handelt sendet es den Chat an das URL Relay

//    /me wird dabei in den Namen umgewandelt

// 2. Das URL Relay sendet den Chat an das das Message Relay, zusammen mit den gespeicherten URLs ausser der eigenen

// 3. Das Message Relay sendet nun den Chat an alle übergebenen URLs

// 4. Jedes angeschlossene URL Relay gibt den Chat aus, ohne den Objekt-Namen davor

//    Aber nur falls es auch eingeschaltet ist, standardmässig ist es Off

// Hinweis: Im OS muss möglicherweise die OpenSim.ini geändert werden

// Dazu muss im Abschnitt [Network] in der Zeile

// user_agent = "OpenSim LSL (Mozilla Compatible)"

// das führende Semikolon entfernt und die Sim neu gestartet werden

string INTERCOM_PASSWORD = "";

string NCNAME = "access";

// Language = 0 German/Deutsch

// Language = 1 English/Englisch

integer Language = 0;

integer SYNC_TIME = 10;

integer BROADCAST = 1000;

integer SEND = 1001;

string MyURL;

list URLs;

list URLs1;

list URLs2;

integer IntercomOn;

key User;

list Access;

integer NCLine;

key NCid;

integer Listener;

integer Handle;

Menu()

{

    string s = "Options description:\n\nAdd URL: Use this to add new Intercoms.\n"

                + "My URL: Use this to get the address of this Intercom.\n"

            + "List URLs: Use this to list all the linked intercoms.\n"

            + "Reset: Use this to permanently reset the current Intercom since resetting "

            + "maybe it looses the contact to other Intercoms.\n"

            + "On/Off: This will turn the intercom on and off. It will remain connected "

            + "to the network but will not receive or broadcast messages.";

        string s1 = "Beschreibung der Optionen\n\nAdd URL: URLs von anderen Intercoms hinzufügen\n"

            + "My URL: Ruft die eigene URL ab\n"

            + "List URLs: Listet alle verbundenen Intercom-URLs auf\n"

            + "Reset: Setzt das Intercom zurück "

            + "und kann dadurch den Kontakt zu anderen Intercoms verlieren\n"

            + "On/Off: Schaltet das Intercom ein/aus, bleibt aber verbunden, "

            + "sendet oder empfängt aber keine Nachrichten mehr";

        list l = ["Add URL", "My URL", "List URLs", "Reset", "On", "Off"];

        integer Channel = (integer)llFrand(99999) + 999;

        Listener = llListen(Channel, "", User, "");

        if(Language == 1) llDialog(User, s, l, Channel);

        else llDialog(User, s1, l, Channel);

}

NewURL()

{

    integer x = llListFindList(URLs, [MyURL]);

    if(x != -1) URLs = llDeleteSubList(URLs, x, x);

    x = llListFindList(URLs1, [MyURL]);

    if(x != -1) URLs1 = llDeleteSubList(URLs1, x, x);

    x = llListFindList(URLs2, [MyURL]);

    if(x != -1) URLs2 = llDeleteSubList(URLs2, x, x);

    llReleaseURL(MyURL);

    MyURL = "";

    llRequestURL();

}

Say(string s)

{

    string s1 = llGetObjectName();

    integer x = llSubStringIndex(s, " ");

    if(x != -1)

    {

        string s2 = llGetSubString(s, 0, x - 1);

        s = llDeleteSubString(s, 0, x -1);

        s = "/me" + s;

        llSetObjectName(s2);

    }

    llSay(0, s);

    llSetObjectName(s1);

}

integer HasAccess(key k)

{

    if(k == llGetOwner()) return TRUE;

    string s = llKey2Name(k);

    if(llListFindList(Access, [s]) != -1) return TRUE;

    return FALSE;

}

default

{

    on_rez(integer param)

    {

        NewURL();

    }

    changed(integer change)

    {

        if (change & (CHANGED_REGION_START | CHANGED_REGION)) NewURL();

        if(change & CHANGED_INVENTORY) llResetScript();

    }

    state_entry()

    {

        IntercomOn = FALSE;

        NewURL();

        llSetTimerEvent(SYNC_TIME);

        NCLine = 0;

        if(llGetInventoryType(NCNAME) == INVENTORY_NOTECARD) NCid = llGetNotecardLine(NCNAME, NCLine++);

    }

    http_request(key id, string method, string body)

    {

        if (method == URL_REQUEST_GRANTED)

        {

            MyURL = body;

            URLs += [body];

            return;

        }

        if (method == URL_REQUEST_DENIED)

        {

            NewURL();

            return;

        }

        if (method == "POST")

        {

            list l = llParseString2List(body, [" "], [""]);

            if(llList2String(l, 1) != INTERCOM_PASSWORD) return;

            if(llListFindList(URLs, [llList2String(l, 0)]) != -1) return;

            URLs += [llList2String(l, 0)];

            llHTTPResponse(id, 200, "OK");

            return;

        }

        if (method == "PUT")

        {

            if (!IntercomOn) return;

            Say(body);

            llHTTPResponse(id, 200, "OK");

            return;

        }

    }

    http_response(key id, integer status, list metadata, string body)

    {

        if (status >= 400 && status <= 404)

        {

            integer i;

            for(i = 0; i < llGetListLength(URLs); i++)

            {

                if (llSubStringIndex(body, llList2String(URLs, i)) != -1) URLs = llDeleteSubList(URLs, i, i);

            }

            for(i = 0; i < llGetListLength(URLs1); i++)

            {

                if (llSubStringIndex(body, llList2String(URLs1, i)) != -1) URLs1 = llDeleteSubList(URLs1, i, i);

            }

            for(i = 0; i < llGetListLength(URLs2); i++)

            {

                if (llSubStringIndex(body, llList2String(URLs2, i)) != -1) URLs2 = llDeleteSubList(URLs2, i, i);

            }

        }

    }

    link_message(integer sender_num, integer num, string str, key id)

    {

        if (!IntercomOn || num != BROADCAST) return;

        integer x = llListFindList(URLs, [MyURL]);

        list l = llDeleteSubList(URLs, x, x);

        if (llGetListLength(l) == 0) return;

        llMessageLinked(LINK_THIS, SEND, llList2CSV(l), str);

    }

    timer()

    {

        llSetTimerEvent((float)FALSE);

        if (llGetListLength(URLs1) == 0)

        {

            URLs1 = URLs;

            URLs2 = llDeleteSubList(URLs2, 0, 0);

        }

        if (llGetListLength(URLs2) == 0)

        {

            URLs2 = URLs;

        }

        if(llList2String(URLs1, 0) != "" && llList2String(URLs2, 0) != "")

        {

            llHTTPRequest(llList2String(URLs1, 0),

                [HTTP_METHOD, "POST"],

                llList2String(URLs2, 0) + " " + INTERCOM_PASSWORD);

        }

        URLs1 = llDeleteSubList(URLs1, 0, 0);

        llSetTimerEvent(SYNC_TIME);

    }

    dataserver(key requested, string data)

    {

        if(requested == NCid)

        {

            if(data != EOF)

            {

                data = llStringTrim(data, STRING_TRIM);

                if(data != "") Access += [data];

                NCid = llGetNotecardLine(NCNAME, NCLine++);

            }

        }

    }

    listen(integer channel, string name, key id, string message)

    {

        llListenRemove(Listener);

        llListenRemove(Handle);

        if(message == "On")

        {

            IntercomOn = TRUE;

            if(Language == 1) llInstantMessage(id, "Intercom is now: ON");

            else llInstantMessage(id, "Intercom ist nun: AN");

            return;

        } else if(message == "Off")

        {

            IntercomOn = FALSE;

            if(Language == 1) llInstantMessage(id, "Intercom is now: OFF");

            else llInstantMessage(id, "Intercom ist nun: AUS");

            return;

        } else if(message == "My URL")

        {

            if (MyURL == "")

            {

                if(Language == 1) llInstantMessage(id, "I don't have an URL registered yet.");

                else llInstantMessage(id, "Ich habe noch keine registrierte URL.");

                return;

            }

            if(Language == 1) llInstantMessage(id, "My URL is: " + MyURL);

            else llInstantMessage(id, "Meine URL lautet: " + MyURL);

        } else if(message == "Add URL")

        {

            if(Language == 1)

            {

                llInstantMessage(id, "Please paste an URL on channel " + (string)89

                    + " in order to register it with the system by typing:\n/" + (string)89

                    + " URL\nWhere URL is the URL of another intercom.");

            } else

            {

                llInstantMessage(id, "Bitte kopiere eine URL auf Kanal " + (string)89

                    + ", um die URL im System zu registrieren. Tippe dazu \n/" + (string)89

                    + " URL\n wobei URL die URL eines anderen Intercoms ist.");

            }

            Handle = llListen(89, "", id, "");

            return;

        } else if(message == "List URLs")

        {

            if(llGetListLength(URLs) == 0)

            {

                if(Language == 1) llInstantMessage(id, "No URLs registered.");

                else llInstantMessage(id, "Es sind keine URLs registriert.");

                return;

            }

            integer i;

            for(i = 0; i < llGetListLength(URLs); i++) llSay(0, llList2String(URLs, i));

            return;

        } else if(message == "Reset")

        {

            llSetTimerEvent(0);

            llResetScript();

            return;

        } else if(channel == 89)

        {

            message = llStringTrim(message, STRING_TRIM);

            if(message == "") return;

            if(llListFindList(URLs, [message]) != -1)

            {

                if(Language == 1) llInstantMessage(id, "URL already exists.");

                else llInstantMessage(id, "Dies URL gibt es bereits.");

                return;

            }

            URLs += [message];

            if(Language == 1) llInstantMessage(id, "URL: " + message + " has been registered.");

            else llInstantMessage(id, "URL: " + message + " wurde registriert.");

            return;

        }

    }

    touch_start(integer total_number)

    {

        User = llDetectedKey(0);

        if(HasAccess(User)) Menu();

    }

}

Unsichtbare Energiebarriere/Schild

Sun, 15 Sep 2013 17:49:46 +0200

Stopft man das Script in ein Prim, wird dieses unsichtbar. Wenn jemand dagegen rennt, blitzt es kurz auf u. glüht einige Sekunden in der angegebenen Farbe
Falls Textur u. passender Sound vorhanden sind, können die mitverwendet werden.

Code:
// Unsichtb. Energieschild

// MoniTill 9.13 V1

// Lizenz: Gemeinfrei (Public Domain)

string energietex = "";            //Wenn eine Textur im Verzeichnis liegt, hier den Namen eintragen

string energiesound ="";        //Falls eine Sounddatei im Verzeichnis liegt, hier den Namen eintragen

float transparenzgrad = 0.7;         // 0 = unsichtbar 1= voll sichtbar

float dauer = 3;            // Dauer in Sekunden

float gluehstrk = 0.2;            // Glühstärke 0 = Kein Glühen 1= hell weiß

vector grundfarbe =<1,0,0>;        // rot,grün,blau Farbe 

default

{

    state_entry()

    {

       if (energietex != "")

       {

          llSetTexture( energietex, ALL_SIDES );

          llSetTextureAnim( ANIM_ON | ROTATE | LOOP, ALL_SIDES, 0, 0, 0, TWO_PI, 10 );

        }                   

        llSetPrimitiveParams([ PRIM_GLOW, ALL_SIDES, 0 , PRIM_COLOR, ALL_SIDES, 

          grundfarbe, 0.0] ); 

    }

    collision_start( integer num )

    {

        if (energiesound != "")

        {

           llTriggerSound( energiesound, 0.5 );

        }

        llSetPrimitiveParams([ PRIM_GLOW, ALL_SIDES, gluehstrk , PRIM_COLOR, ALL_SIDES, 

          <1.0, 1.0, 1.0>, transparenzgrad] ); 

        llSleep(0.3);

        llSetColor(grundfarbe, ALL_SIDES);

        llSleep(dauer);  

        llSetPrimitiveParams([ PRIM_GLOW, ALL_SIDES, 0 , PRIM_COLOR, ALL_SIDES, 

          grundfarbe, 0.0] ); 

    }

}

Einfache, leicht erweiterbare NPC Steuerung

Wed, 14 Aug 2013 13:38:53 +0200

Hallöchen!

Ich wollte auf einer Sim ein NPC als Maskottchen umherwandern lassen.
Dazu habe ich mir ein einfaches System mit drei kleinen Scripten ausgedacht. Da es auch andere vielleicht gebrauchen können,
poste ich es frech hierher ^^

Das erste Script kommt in den NPC (bzw. in ein Objekt was er trägt).
Er wandert dann zum ersten Checkpoint, wo er sein nächstes Ziel abfragt.

Das zweite Script kommt in die Checkpoints, die an alle Abzweigungen gebaut werden. Es enthält alle UUIDs der erreichbaren Nachbar – Checkpoints
und wählt per Zufall einen davon aus. Ich habe mir dafür einen kleinen Phantomwürfel gerezzt, den ich wg der
begrenzten Reichweite (um Überschneidungen in Räumen zu vermeiden "hört" der NPC nur 1,5m weit auf Befehle) auf halber Avatarhöhe schweben lasse.

Und das dritte Script kommt in ein Schalterobjekt um die Checkpoints simweit sichtbar/unsichtbar zu schalten.

Das Script für den NPC:

Code:
// NPC Steuerungssystem 

// MoniTill 8.13 V1

// Lizenz: Gemeinfrei (Public Domain)

// Script für Objekt am Avatar/NPC

key zielchkp = "0c3a6a5b-df1f-4d43-8370-775cfc1fbcda"; // Den ersten Checkpoint nach dem Rezzen ansteuern

//  Diese Zeile muss angepasst werden. Der Rest nur bei Bedarf

integer NPCkanal = 15432; // Der Kanal für das System. Falls NPCs unterschiedliche Wege nutzen sollen, einfach versch. Kanäle verw.

vector ziel;

vector altziel;

float maxZeit = 60 ; //Wenn in 60 Sek. noch nicht am Ziel, wird er wohl aufgehalten, also Teleport und fertig!^^

float startzeit;

integer fragenzaehler;      // Wenn er zurück soll, fragt er mehrmals (5x)nach. 

                            // Falls dann immer noch der alte Checkpoint kommt, 

                            // steckt er wohl in einer Sackgasse u. muss wirklich zurück

integer flag;

// Für die Verwendung in SL muss osNpcMoveToTarget u. osIsNpc entfernt u. osTeleportOwner ersetzt werden

// dann sollte es auch dort laufen.... glaube ich :O)..

default

{

    state_entry()

    {

        llSetStatus(STATUS_PHYSICS, TRUE);

        llSleep(10);

    llResetTime();

        list checkpointPOSstr = llGetObjectDetails(zielchkp,[OBJECT_POS]);

    ziel = llList2Vector(checkpointPOSstr,0); 

    llSetTimerEvent(2.0);     

    llListen( NPCkanal, "", NULL_KEY, "" ); 

    }

    timer()

    {

    key  npc=llGetOwner();

    if (osIsNpc(npc) == TRUE)

    {

        //Wenn er als echter NPC unterwegs ist, gilt diese Zeile....

        osNpcMoveToTarget(npc,ziel, OS_NPC_NO_FLY) ;

    } 

    else 

    {

        //..und beim Test mit Viewer gilt diese.

        llMoveToTarget(ziel,0.05);     

        // Bei Verwendung in SL muss die "if/else" Schleife weg und nur der llMoveToTarget stehen bleiben

     }  

    if (llVecDist(ziel,llGetPos()) < 1.5)

    {

        flag= 1;

        llWhisper(NPCkanal,"*ziel*");

        llResetTime();

        startzeit=llGetTime();

    }

    if (startzeit +maxZeit < llGetTime() )

    {

        osTeleportOwner(ziel,ZERO_VECTOR);

        // Bei Verwendung in SL muss dieser Befehl ersetzt werden

    }

   }

   listen( integer channel, string name, key id, string msg)  

   {  

      list checkpointPOSstr = llGetObjectDetails(id,[OBJECT_POS]);

      vector checkpointPOS = llList2Vector(checkpointPOSstr,0);

      float distanz = llVecDist(checkpointPOS,llGetPos());

      if (flag == 1 && llGetSubString(msg, 0, 5)== "*gehe*" && distanz < 1.5)

      {

        vector msgz =(vector)llGetSubString(msg, 6, -1); 

        if (msgz != altziel  || fragenzaehler > 4 )

        {

            //llWhisper(0,(string)fragenzaehler + (string)ziel+ (string)altziel); 

            altziel = ziel;

            ziel = msgz; 

            flag= 0;

            fragenzaehler = 0;

        }

        else

        {

            fragenzaehler += 1;

        }

      }   

   }

}

Das Script für die Checkpoints:

Code:
// NPC Steuerungssystem 

// MoniTill 8.13 V1

// Lizenz: Gemeinfrei (Public Domain)

// Script für die Checkpoints

 // Liste der anderen Checkpoints, die von diesem ohne Hindernisse erreichbar sind 

list npcWeg = ["4f081952-f657-4e78-8b8b-f9633ae7729f","0c3a6a5b-df1f-4d43-8370-775cfc1fbcda"];

 // Diese Zeile muss angepasst werden. Der Rest nur bei Bedarf

integer NPCkanal = 15432;  // Der Kanal für das System

integer i;

integer ii;

key npc;  

integer randInt(integer n)

{

      return (integer)llFrand(n + 1);

}

integer randIntBetween(integer min, integer max)

{

      return min + randInt(max - min);

} 

default

{

    state_entry()

    {

        ii = llGetListLength(npcWeg); 

    llListen( NPCkanal, "", NULL_KEY, "" ); 

    }

    listen( integer channel, string name, key id, string msg)  

    {

    if (msg == "ckptranson")

    {

        llSetAlpha(0.0, ALL_SIDES);

    }

    if (msg == "ckptransoff")

    {

        llSetAlpha(1.0, ALL_SIDES);

    }

    if (msg == "*ziel*")

    {

        i = randIntBetween(0, ii - 1);

        string checkpointPOSstr =llList2String( llGetObjectDetails(llList2String(npcWeg,i),[OBJECT_POS]),0);

        llWhisper(NPCkanal,"*gehe*"+checkpointPOSstr );

    }

   }

}

Das Script für den Schalter:

Code:
// NPC Steuerungssystem 

// MoniTill 8.13 V1

// Lizenz: Gemeinfrei (Public Domain)

// Script für Schalter um die Checkpoints unsichtbar/sichtbar zu machen

integer NPCkanal = 15432; // Der Kanal für das System

integer ckptrans;

default

{

   touch_start(integer nummer)

   {

        if(ckptrans == 0)

        {

            llRegionSay(NPCkanal,"ckptranson");

        ckptrans = 1;

        }

        else 

        {

            llRegionSay(NPCkanal,"ckptransoff");

        ckptrans = 0;

        }

   }

}

(Fast) weiche Bewegung - Tour Skript

Mon, 08 Apr 2013 20:58:54 +0200

Basierend auf dem VogelSkript von Kayaker Magic (zu finden hier) hab ich mal ein Tour-Skript gebastelt, das Wegpunkte abfährt, auch mal etwas verweilt und/oder Text ausgibt. Im OSgrid hab ich damit fast flüssige Bewegungen hinbekommen, auf meiner Insel leider nicht weils da momentan ziemlich laggt. Das hängt wohl auch von der Grösse des Objektes ab. Nötig ist dazu nur eine Notecard namens config, wo die Wegpunkte in der Form
DRIVE = =
drinstehen. Die letzte Position sollte natürlich die Ausgangspostion sein.
Unter dem jeweiligen Wegpunkt kann auch noch eine Pause angegeben werden.
PAUSE = Sekunden
Und/oder auch ein Text der ausgegeben werden soll.
TEXT = Text
Mit der Konstanten TIME kann im Skript eingestellt werden wie schnell sich das Objekt bewegt, mit 1.0 ist es etwa 1 Meter/Sekunde. Grösser = schneller, aber auch mehr Ruckeln.
Und hier das Skript:

Code:
// Tour script by Rebekka Revnik

// it's free for everyone, no restrictions

// you may delete my name and claim it as your own script

// but if you give credit it would be nice :-)

// the first part is not mine, thanks and credits goes to Kayaker :-)

// Single Framed (SF) motion without llKeyframedMotion

// original script : Kayaker Magic

// from: http://forums.osgrid.org/viewtopic.php?f=5&t=4577

// minor changes by me

vector      SF_spos;        //start position

rotation    SF_srot;        //starting rotation

float       SF_stime;       //starting time

vector      SF_epos;        //ending position

rotation    SF_erot;        //ending rotation

float       SF_seconds;     //time to move that distance

integer     SF_target=-1;      //handle of last target position

SFrame()

{

    SF_spos=llGetPos();

    SF_srot=llGetRot();

    SF_stime=llGetTime();

    SF_epos = llList2Vector(Points, Count);

    SF_erot = llList2Rot(Rots, Count);

    SF_seconds=llVecDist(SF_epos, llGetPos()) / TIME;

    rotation t=;

    if ((t.x*t.x + t.y*t.y + t.z*t.z + t.s*t.x)>0.5) SF_erot = <-SF_erot.x,-SF_erot.y,-SF_erot.z,-SF_erot.s>;

    llTargetRemove(SF_target);

    SF_target=llTarget(SF_epos, 0.1);

}

integer SFnotat()

{

    if (SF_target== -1) return TRUE;

    float time=llGetTime();

    time = (time-SF_stime)/SF_seconds;

    if (time>1.0)

    {

        llTargetRemove(SF_target);

        SF_target=-1;

        llSetLinkPrimitiveParamsFast(LINK_THIS,[PRIM_POSITION,SF_epos,PRIM_ROTATION,SF_erot]);

        return TRUE;

    }

    float emit= 1.0-time;

    vector pos=SF_epos*time+SF_spos*emit;

    rotation rot = <

        SF_erot.x*time+SF_srot.x*emit,

        SF_erot.y*time+SF_srot.y*emit,

        SF_erot.z*time+SF_srot.z*emit,

        SF_erot.s*time+SF_srot.s*emit

            >;

    emit = llSqrt(rot.x*rot.x+rot.y*rot.y+rot.z*rot.z+rot.s*rot.s);

    rot = ;

    llSetLinkPrimitiveParamsFast(LINK_THIS,[PRIM_POSITION,pos,PRIM_ROTATION,rot]);

    return FALSE;

}

// ab hier hab ich das geschrieben :-)

// Mach dir eine Notecard mit den folgenden Einträgen

// Gross/Kleinschreibung ist nicht wichtig, also DRIVE ist genauso gut wie drive oder Drive

// DRIVE = Position = Rotation        die Wegpunkte eben, mit Position und Rotation

// nach dem Wegpunkt (muss aber nicht sein)

// PAUSE = Sekunden                    hält das Objekt ne Weile an

// TEXT = text                        sagt den Text im Chat

// now that's my part :-)

// Make a notecard with the folling entries

// it's not case sensitive, for example drive is accepted as DRIVE or Drive

// DRIVE = Position = Rotation        the waypoints with given params

// after the waypoint (optionally but but not required)

// PAUSE = seconds                    makes the object to stay for a while

// TEXT = text                        says the text in chat

// wie es oben steht, die Schlüsselwörter

// as above, the keywords

string DRIVE = "drive";

string PAUSE = "pause";

string TEXT = "text";

// Name der Notecard

// name of the notecard

string NCNAME = "config";

// Trennzeichen für die Schlüsselwörter

// separator for keywords

string SEPARATOR = "=";

// wie schnell sich das Objekt bewegt

// 1 ist ungefähr 1 Meter pro Sekunde

// Grösser = schneller, aber auch mehr ruckeln

// how fast your object will move

// 1 means appr. 1 m per second

// a greater number ist faster but less smoothly

float TIME = 1.0;

// Stell es auf TRUE, dann kommen Infos im Chat über die Wegpunkte

// set it to TRUE to get informations about the waypoints in chat

integer DEBUG = FALSE;

// Wähle die Sprache, ich kann nur die beiden unten sprechen

// 0 = deutsch, 1 = englisch

// choose language, I speak only the two below

// 0 for german, 1 for english

integer LANGUAGE = 0;

list Points;

list Rots;

list Pause;

list Text;

integer NCLine;

key NCid;

integer Count;

// liest ein Zeile aus der Notecard und speichert sie

// reads a notecard line and saves it

Read(string data)

{

    list l = llParseString2List(data, [SEPARATOR], []);

    string s1 = llToLower(llStringTrim(llList2String(l, 0), STRING_TRIM));

    vector v1 = (vector)llToLower(llStringTrim(llList2String(l, 1), STRING_TRIM));

    rotation r1 = (rotation)llToLower(llStringTrim(llList2String(l, 2), STRING_TRIM));

    integer x;

    if(s1 == DRIVE)

    {

        if(v1 != ZERO_VECTOR)

        {

            Points += [v1];

            Rots += [r1];

            Pause += [0];

            Text += [""];

        }

    } else if(s1 == PAUSE)

    {

        x = llGetListLength(Pause) - 1;

        Pause = llListReplaceList(Pause, [(float)llToLower(llStringTrim(llList2String(l, 1), STRING_TRIM))], x, x);

    } else if(s1 == TEXT)

    {

        x = llSubStringIndex(data, SEPARATOR);

        data = llDeleteSubString(data, 0, x);

        x = llGetListLength(Text) - 1;

        Text = llListReplaceList(Text, [llStringTrim(data, STRING_TRIM)], x, x);

    }

}

// Sagt was in der Notecard steht (TEXT = text), ohn den Objektnamen

// es muss aber ein Leerzeichen drin sein und mindestens zwei Wörter haben

// sonst kommt nur der normale Chat mit dem Objektnamen

// says what you wrote in the notecard (TEXT = text) without the object name

// it has to be a space in it and at least two words

// otherwise you'll get only the normal chat with the object name

Say(string s)

{

    string s1 = llGetObjectName();

    integer x = llSubStringIndex(s, " ");

    if(x != -1)

    {

        string s2 = llGetSubString(s, 0, x - 1);

        s = llDeleteSubString(s, 0, x -1);

        s = "/me" + s;

        llSetObjectName(s2);

    }

    llSay(0, s);

    llSetObjectName(s1);

}

default

{

    state_entry()

    {

        llSetText("", <1,1,1>, 1.0);

        Points = [];

        Rots = [];

        Pause = [];

        Text = [];

        if(llGetInventoryType(NCNAME) == INVENTORY_NONE)

        {

            if(LANGUAGE == 0) llOwnerSay("Keine config-NC gefunden.");

            else if(LANGUAGE == 1) llOwnerSay("No config nc found.");

        } else

        {

            if(LANGUAGE == 0) llOwnerSay("Lese config, bitte warten...");

            else if(LANGUAGE == 1) llOwnerSay("Reading config nc, please wait...");

            NCLine = 0;

            NCid = llGetNotecardLine(NCNAME, NCLine++);

        }

    }

    dataserver(key requested, string data)

    {

        if(requested == NCid)

        {

            if(data != EOF)

            {

                Read(data);

                NCid = llGetNotecardLine(NCNAME, NCLine++);

            } else

            {

                if(LANGUAGE == 0) llOwnerSay("Fertig.");

                else if(LANGUAGE == 1) llOwnerSay("Ready.");

                if(llGetListLength(Points) == 0)

                {

                    if(LANGUAGE == 0) llOwnerSay("Keine Wegpunkte gefunden.");

                    else if(LANGUAGE == 1) llOwnerSay("No waypoints found.");

                }

                else

                {

                    if(LANGUAGE == 0) llOwnerSay((string)llGetListLength(Points) + " Wegpunkte gelesen.");

                    else if(LANGUAGE == 1) llOwnerSay((string)llGetListLength(Points) + " waypoints read.");

                    state running;

                }

            }

        }

    }

}

state running

{

    state_entry()

    {

        if(LANGUAGE == 0) llSetText("Sitze und berühre mich", <1,1,1>, 1.0);

        else if(LANGUAGE == 1) llSetText("Sit down and touch me", <1,1,1>, 1.0);

    }

    touch_start(integer total_number)

    {

        state drive;

    }

}

state drive

{

    state_entry()

    {

        llSetText("", <1,1,1>, 1.0);

        Count = 0;

        // Ändere den Text hier drunter nach deinen Wünschen. Der kommt nur beim Start der Tour

        // Change the text below as you like. It appears only at the start of the tour

        Say("Willkommen bei der Tour auf meiner Insel. Sie dauert etwa 20 Minuten. Viel Spass :-)");

        SFrame();

    }

    not_at_target()

    {

        if(SFnotat())

        {

            if(DEBUG)

            {

                if(LANGUAGE == 0) llOwnerSay("Wegpunkt Nr. " + (string)(Count + 1) + " bei " + (string)llList2Vector(Points, Count));

                else if(LANGUAGE == 1) llOwnerSay("waypoint no. " + (string)(Count + 1) + " at " + (string)llList2Vector(Points, Count));

            }

            if(llList2String(Text, Count) != "") Say(llList2String(Text, Count));

            if(llList2Float(Pause, Count) > 0) llSleep(llList2Float(Pause, Count));

            Count++;

            if(Count == llGetListLength(Points)) state running;

            SFrame();

        }

    }

}

Hybrid-Poseball

Thu, 24 Jan 2013 13:16:06 +0100

Fast vergessen: Mandarine hat vor einiger Zeit einen Poseball-Rezzer geskriptet. Ist eigentlich für Single und Couple Dances gedacht, geht aber auch für alles andere. Ich find das viel einfacher zu bedienen als den unsäglichen MPLV. Einfach mal ausprobieren :-)
Und hier gehts lang: LINK

AO für OpenSim

Wed, 05 Dec 2012 20:03:23 +0100

Neulich hatte ich nach einem AO gesucht und auch von Freunden welche bekommen. Die haben auch funktioniert, nur waren die eben entweder no Mod oder es war nicht alles drin was ich mir gewünscht hätte. Also hab ich kurzerhand einen eigenen AO geskriptet (was ich eigentlich vermeiden wollte). Dabei ist auch gleich noch ein Tanzball- und ein Poledance-Skript rausgekommen, aber das später. Hier ist nun der Extrakt.

Kurzbeschreibung: Der AO überschreibt die Animationen in 26 Kategorien inklusive Typing. Ausserdem sind auch Tänze als 27. Kategorie vorhanden. Es gibt keine Beschränkung in der Anzahl der Animationen, allerdings sind mehrere nur in einigen Kategorien sinnvoll. Zudem sollte es auch in No-Script-Zonen funktionieren, aber beim Test auf Wright Plaza gings trotzdem nicht. Das control Event verhält sich wohl im OS anders als in SL.
Achja das Skript ist nur für OpenSim geeignet, aber mit kleinen Änderungen geht es auch in SL. Ich habs ins Skript geschrieben wo.

Bei Reset liest das Skript eine Notecard namens config ein. Dort müssen die Animationen in der Form

AnimType = Typ der Animation (zB Walking)
Animation 1
Animation 2
...

eingetragen werden (Beispiel weiter unten). Es können pro Animationstyp so viele Animationen eingetragen werden wie gewünscht (keine Beschränkung auf 12 pro Typ), allerdings kann man nur bei Walks, Stands, Sits, Groundsits und Tänzen auswählen, bei allen anderen wird einfach die letzte genommen. Natürlich müssen die Animationen auch im Objekt sein, sonst gibts eine Meldung. Wenn in einer Kategorie nichts steht passiert auch nichts.
Für den AO selber hab ich einfach zwei Prims zusammengelinkt und Texturen für Ein/Aus bzw. das Menü aufgebracht bzw. hineingelegt. Die Texturen hab ich von Marg's AO, dort liegen sie Full Perm drin.
Im Hauptmenü kann man in die einzelnen Untermenüs verzweigen sowie sich auf den Boden setzen oder wieder aufstehen. Im Optionsmenü wird die Zeit für die Stands eingestellt und Art der Wechsel der Stands (nur einen Stand, der Reihe nach oder zufällig). Ausserdem kann man das Sitzen ein- bzw ausschalten. In allen anderen Menüs wählt man die entsprechende Animation.
Der AO wird ans HUD an Bottom Right angehängt und verschiebt sich in den sichtbaren Bereich. Bei anderen Punkten muss man ihn verschieben oder den Wert von LocalPos im Skript ändern.
Leider kann ich mein eigenes AO nicht weitergeben, weil die Animationen No Trans sind (ok ein leeres vielleicht). Dafür gibts das Skript umsonst :-)
Viel Spass

Code:
string CAT = "AnimType";                    // Kennzeichnugn für Kategorie in der NC

integer LinkOn = 1;                            // Linknummer zum Ein/Ausschalten

integer LinkMenu = 2;                        // LinkNummer fürs Menü

string TextureOff = "Button.Off";            // Textur wenn der AO aus ist

string TextureOn = "Button.On";                // Textur wenn der AO an ist

vector LocalPos = <0.000000,0.058893,0.126620>;    // Verschiebung bei Anhängen an Bottom Right

list AnimTypes = ["Sitting on Ground", "Sitting", "Striding", "Crouching", "CrouchWalking",

"Soft Landing", "Standing Up", "Falling Down", "Hovering Down", "Hovering Up",

"FlyingSlow", "Flying", "Hovering", "Jumping", "PreJumping", "Running",

"Turning Right", "Turning Left", "Walking", "Landing", "Standing",

"Swimming Down", "Swimming Up", "Swimming Forward", "Floating", "Typing",

"Dance"];

// Variablen und Konstanten für die NC

string NCNAME = "config";                    // Name der Notecard

integer NCLine;                                // die aktuelle Zeile der NC

key NCid;                                    // Kennung der NC

integer State;                                // Abschnitt beim Einlesen

integer Count;                                // Anzahl der gelesenen Anis

// Variablen und Konstanten fürs Animieren

list Stands;                                // Liste der Stand-Anis

list Sits;                                    // Liste der Sitz-Anis

list Walks;                                    // Liste der Walk-Anis

list GroundSits;                            // Liste der Groundsits

list Dances;                                // Liste der Tänze

list Anims;                                    // Liste der Animationen (einer pro Typ)

integer StandTime = 40;                        // Dauer bis zur nächsten Stand-Ani

integer StandType = 2;                        // 0 = fest, 1 = nacheinander, 2 = zufällig

integer CurAnimType;                        // der Typ der aktuellen Animation

string CurAni;                                // der Name der aktuellen Animation

integer SitAlways = FALSE;                    // Sitzen überschreiben

integer TempType;                            // zum Wiederherstellen nach Tippseln

string TempAni;                                // zum Wiederherstellen anch Tippseln

integer On;                                    // HUD ein oder aus

float TIME = 0.25;                            // Zeit für Timer

// Variablen und Konstanten fürs Menü

string NEXT = ">>>";                        // Schaltflächen für vor und zurück

string PREV = "<<<";

string DlgTitle;                            // Dialog-Text

integer DlgChannel;                             // Chatkanal

list DlgItems = [];                             // die Schaltflächen des Dialogs

integer DlgPage = 0;                        // aktuelle Seite - wird vom Skript verwendet

integer DlgType = -1;                        // das aktuelle Menü

integer Listener;                            // ID für den Kanal

integer DlgNo = FALSE;                        // wenn TRUE, Anzeige mit Zahlen auf den Tasten

// allgemeines Menü

Menu()

{

    list l = ["Ende"];

    if(DlgType > 1) l += ["Zurück"];

    if(DlgType == 7) l += ["Stop"];

    list l1;

    list l2;

    integer x = llGetListLength(DlgItems);

    integer len1 = 12 - llGetListLength(l);

    integer len2 = len1 - 1;

    integer len3 = len2 - 1;

    integer start = (DlgPage - 1) * len3 + len2;

    if(DlgPage == 0)

    {

        start = 0;

        if(x <= len1) l2 = l + llList2List(DlgItems, 0, len2);

        else

        {

            l2 = l + llList2List(DlgItems, 0, len3);

            l2 = llListInsertList(l2, [NEXT], 2);

        }

    } else

    {

        llSay(0, (string)(x - start + llGetListLength(l)));

        if((x - start + llGetListLength(l)) < 12)

        {

            l2 = l + llList2List(DlgItems, start, start + len3);

            l2 = llListInsertList(l2, [PREV], 0);

        } else

        {

            l2 = l + llList2List(DlgItems, start, start + len3 - 1);

            l2 = llListInsertList(l2, [NEXT], 2);

            l2 = llListInsertList(l2, [PREV], 0);

        }

    }

    l1 = [];

    x = 0;

    string s;

    string s1 = "";

    integer i;

    if(DlgNo)

    {

        for(i = 0; i < llGetListLength(l2); i++)

        {

            s = llList2String(l2, i);

            if(llListFindList(l, [s]) != -1 || s == NEXT || s == PREV) l1 += [s];

            else

            {

                l1 += [++start];

                s1 += (string)start + " - " + s +"\n";

            }

        }

    } else l1 = l2;

    llListenRemove(Listener);

    Listener = llListen(DlgChannel, "", llGetOwner(), "");

    llDialog(llGetOwner(), DlgTitle + "\n" + s1, l1, DlgChannel);

}

// allgemeine Menüprozedur

integer DlgMain(string msg)

{

    llListenRemove(Listener);

    if(msg == PREV)

    {

        DlgPage--;

        Menu();

        return TRUE;

    } else if(msg == NEXT)

    {

        DlgPage++;

        Menu();

        return TRUE;

    } else if(msg == " ")

    {

        Menu();

        return TRUE;

    }

    else return FALSE;

}

// Hauptmenü

Menu1()

{

    DlgItems = ["Reset", "Optionen", "Hinsetzen", "Dance", "Stands", "Walks", "Sits", "Groundsits"];

    if(CurAnimType == 0) DlgItems = llListReplaceList(DlgItems, ["Aufstehen"], 2, 2);

    DlgTitle = "Wähle eine Kategorie:";

    DlgType = 1;

    DlgPage = 0;

    DlgNo = FALSE;

    Menu();

}

// Optionsmenü

Menu2()

{

    DlgItems = ["Stand 20s", "Stand 40s", "Stand 60s", "Stand 80s", "Stand 100s"];

    DlgItems += ["Zufällig", "Reihe", "Fest"];

    if(SitAlways) DlgItems += ["Sitzen aus"]; else DlgItems += ["Sitzen an"];

    DlgTitle = "Standzeit: " + (string)StandTime + " s\nWiederholung: ";

    if(StandType == 0) DlgTitle += "Fest";

    else if(StandType == 1) DlgTitle += "Nacheinander";

    else if(StandType == 2) DlgTitle += "Zufällig";

    DlgTitle += "\nImmer Sitzen: ";

    if(SitAlways) DlgTitle += "an\n"; else DlgTitle += "aus\n";

    DlgTitle += "Wähle eine Option:";

    DlgType = 2;

    DlgPage = 0;

    DlgNo = FALSE;

    Menu();

}

// Menü für Stands

Menu3()

{

    DlgItems = Stands;

    DlgTitle = "Wähle einen Stand\nAktueller Stand: " + llList2String(Anims, 20);

    DlgType = 3;

    DlgPage = 0;

    DlgNo = TRUE;

    Menu();

}

// Menü für Walks

Menu4()

{

    DlgItems = Walks;

    DlgTitle = "Wähle einen Walk:\nAktueller Walk: " + llList2String(Anims, 18);

    DlgType = 4;

    DlgPage = 0;

    DlgNo = TRUE;

    Menu();

}

// Menü für Sits

Menu5()

{

    DlgItems = Sits;

    DlgTitle = "Wähle einen Sit:\nAktueller Sit: " + llList2String(Anims, 1);

    DlgType = 5;

    DlgPage = 0;

    DlgNo = TRUE;

    Menu();

}

// Menü für Groundsits

Menu6()

{

    DlgItems = GroundSits;

    DlgTitle = "Wähle einen Groundsit:\nAktueller Groundsit: " + llList2String(Anims, 0);

    DlgType = 6;

    DlgPage = 0;

    DlgNo = TRUE;

    Menu();

}

// Menü für Tänze

Menu7()

{

    DlgItems = Dances;

    DlgTitle = "Wähle einen Tanz:";

    DlgType = 7;

    DlgPage = 0;

    DlgNo = TRUE;

    Menu();

}

// Verarbeitung einer Zeile aus der config

ReadNCLine(string s)

{

    list l = llParseString2List(s, ["="], []);

    s = llStringTrim(llList2String(l, 0), STRING_TRIM);

    if(llToLower(s) == llToLower(CAT))

    {

        s = llStringTrim(llList2String(l, 1), STRING_TRIM);

        integer x = llListFindList(AnimTypes, [s]);

        if(x != -1) State = x;

    } else if(State != -1)

    {

        if(s != "")

        {

            Count++;

            if(State == 0) GroundSits += [s];

            else if(State == 1) Sits += [s];

            else if(State == 18) Walks += [s];

            else if(State == 20) Stands += [s];

            else if(State == 26) Dances += [s];

            Anims = llListReplaceList(Anims, [s], State, State);

            if(llGetInventoryType(s) != INVENTORY_ANIMATION) llOwnerSay("Warnung: Animation " + s + " nicht gefunden.");

        }

    }

    NCid = llGetNotecardLine(NCNAME, NCLine++);

}

//Initialisierung

Init()

{

    integer i;

    SetOff();

    Anims = [];

    GroundSits = [];

    Sits = [];

    Walks = [];

    Stands = [];

    Dances = [];

    CurAnimType = -1;

    CurAni = "";

    State = -1;

    for(i = 0; i < llGetListLength(AnimTypes); i++) Anims += [""];

    DlgChannel = -((integer)llFrand(9999999) - 99999);

}

// startet eine Animation

StartAni(integer Type, string Name)

{

    string s = CurAni;

    CurAni = "";

    if(Type == 1 && !SitAlways)

    {

        CurAnimType = 1;

        return;

    }

    if((Type == 16 || Type == 17) && Name == "") Name = llList2String(Anims, 20);

    else if(Type == 2 && Name == "") Name = llList2String(Anims, 18);        // Striding = Walking

    else if(Type == 5 && Name == "") Name = llList2String(Anims, 19);        // Soft Landing = Landing

    else if(Type == 4 && Name == "") Name = llList2String(Anims, 3);        // Crouch Walking = Crouching

    if(Name != "")

    {

        if(s != "")

        {

            llStopAnimation(s);

            llSleep(0.1);

        }

        llStartAnimation(Name);

        CurAni = Name;

    }

    CurAnimType = Type;

    if(Type == 20 && StandType != 0) llResetTime();

}

// startet den nächsten Stand

NextStand()

{

    string s = llList2String(Anims, 20);

    integer x = llListFindList(Stands, [s]);

    if(StandType == 1)

    {

        x = ++x % llGetListLength(Stands);

    } else if(StandType == 2)

    {

        if(llGetListLength(Stands) > 1)

        {

            do

            {

                x = (integer)llFrand(llGetListLength(Stands));

            } while(llList2String(Stands, x) == s);

        }

    }

    s = llList2String(Stands, x);

    Anims = llListReplaceList(Anims, [s], 20, 20);

    StartAni(20, s);

}

// AO an

SetOn()

{

    On = TRUE;

    llSetLinkTexture(LinkOn, TextureOn, ALL_SIDES);

    CurAni = llGetAnimation(llGetOwner());

    integer x = llListFindList(AnimTypes, [CurAni]);

    StartAni(x, llList2String(Anims, x));

    llSetTimerEvent(TIME);

}

// AO aus

SetOff()

{

    llSetLinkTexture(LinkOn, TextureOff, ALL_SIDES);

    On = FALSE;

    if(CurAni != "") llStopAnimation(CurAni);

    llSetTimerEvent(0.0);

}

default

{

    state_entry()

    {

        Init();

        state readnc;

    }

}

state readnc

{

    state_entry()

    {

        NCLine = 0;

        Count = 0;

        if(llGetInventoryType(NCNAME) != INVENTORY_NOTECARD)

        {

            llOwnerSay("Keine config vorhanden. Angehalten.");

        } else

        {

            NCid = llGetNotecardLine(NCNAME, NCLine++);

            llOwnerSay("Lese config...");

        }

    }

    dataserver(key requested, string data)

    {

        if(requested == NCid)

        {

            if(data != EOF)

            {

                ReadNCLine(data);

            } else

            {

                llOwnerSay((string)Count + " Animationen gelesen.");

                state running;

            }

        }

    }

}

state running

{

    state_entry()

    {

        Listener = llListen(DlgChannel, "", NULL_KEY, "");

        if(llGetAttached()) llRequestPermissions(llGetOwner(), PERMISSION_TRIGGER_ANIMATION | PERMISSION_TAKE_CONTROLS);

    }

    run_time_permissions(integer permissions)

    {

        if(permissions & PERMISSION_TAKE_CONTROLS) llTakeControls(CONTROL_BACK|CONTROL_FWD, TRUE, TRUE);

    }

    changed(integer change)

    {

        if(change & CHANGED_INVENTORY) llResetScript();

        // folgender Block gilt nur für OpenSim

        // für SL bitte löschen

        if(change & CHANGED_ANIMATION)

        {

            if(!On) return;

            string s = llGetAnimation(llGetOwner());

            integer x = llListFindList(AnimTypes, [s]);

            if(x != CurAnimType && x != -1) StartAni(x, llList2String(Anims, x));

        }

        // Blockende

        if(change & CHANGED_TELEPORT) NextStand();

    }

    attach(key attached)

    {

        if(attached != NULL_KEY)

        {

            llSetPos(LocalPos);

            llRequestPermissions(llGetOwner(), PERMISSION_TRIGGER_ANIMATION | PERMISSION_TAKE_CONTROLS);

        }

    }

    timer()

    {

        if(!On) return;

        integer x = llGetAgentInfo(llGetOwner()) & AGENT_TYPING;

        if(x != 0)

        {

            if(CurAnimType != 25 && CurAnimType != 26)

            {

                TempAni = CurAni;

                TempType = CurAnimType;

                StartAni(25, llList2String(Anims, 25));

            }

        } else if(CurAnimType == 25) StartAni(TempType, TempAni);

        else if(llGetTime() >= StandTime)

        {

            if(CurAnimType == 20) NextStand();

            else llResetTime();

        }

        // für SL hier die Kommentarstriche entfernen

        //string s = llGetAnimation(llGetOwner());

        //integer x = llListFindList(AnimTypes, [s]);

        //if(x != CurAnimType) StartAni(x, llList2String(Anims, x));

    }

    touch_start(integer total_number)

    {

        integer x = llDetectedLinkNumber(0);

        if(x == LinkMenu) Menu1();

        else if(x == LinkOn)

        {

            if(On) SetOff(); else SetOn();

        }

    }

    listen(integer channel, string name, key id, string message)

    {

        if(DlgMain(message)) return;

        string s;

        if(DlgType == 1)

        {

            if(message == "Reset") llResetScript();

            else if(message == "Ende") return;

            else if(message == "Optionen")

            {

                Menu2();

                return;

            } else if(message == "Stands")

            {

                Menu3();

                return;

            } else if(message == "Walks")

            {

                Menu4();

                return;

            } else if(message == "Sits")

            {

                Menu5();

                return;

            } else if(message == "Groundsits")

            {

                Menu6();

                return;

            } else if(message == "Dance")

            {

                Menu7();

                return;

            } else if(message == "Hinsetzen")

            {

                StartAni(0, llList2String(Anims, 0));

                Menu1();

                return;

            } else if(message == "Aufstehen")

            {

                llStopAnimation(CurAni);

                CurAni = "";

                CurAnimType = -1;

                NextStand();

                Menu1();

                return;

            }

        } else if(DlgType == 2)

        {

            if(message == "Ende") return;

            else if(message == "Zurück")

            {

                Menu1();

                return;

            } else if(message == "Stand 20s") StandTime = 20;

            else if(message == "Stand 40s") StandTime = 40;

            else if(message == "Stand 60s") StandTime = 60;

            else if(message == "Stand 80s") StandTime = 80;

            else if(message == "Stand 100s") StandTime = 100;

            else if(message == "Zufällig") StandType = 2;

            else if(message == "Reihe") StandType = 1;

            else if(message == "Fest") StandType = 0;

            else if(message == "Sitzen an")

            {

                SitAlways = TRUE;

                if(CurAnimType == 1) StartAni(1, llList2String(Anims, 1));

            } else if(message == "Sitzen aus")

            {

                SitAlways = FALSE;

                if(CurAnimType == 1 && CurAni != "")

                {

                    llStopAnimation(CurAni);

                    CurAni = "";

                    llStartAnimation("sit");

                }

            }

            Menu2();

            return;

        } else if(DlgType == 3)

        {

            if(message == "Ende") return;

            else if(message == "Zurück")

            {

                Menu1();

                return;

            }

            s = llList2String(Stands, (integer)message - 1);

            if(s != "") Anims = llListReplaceList(Anims, [s], 20, 20);

            if(CurAnimType == 20) StartAni(20, s);

            Menu3();

            return;

        } else if(DlgType == 4)

        {

            if(message == "Ende") return;

            else if(message == "Zurück")

            {

                Menu1();

                return;

            } 

            s = llList2String(Walks, (integer)message - 1);

            if(s != "") Anims = llListReplaceList(Anims, [s], 18, 18);

            if(CurAnimType == 18) StartAni(18, s);

            Menu4();

            return;

        } else if(DlgType == 5)

        {

            if(message == "Ende") return;

            else if(message == "Zurück")

            {

                Menu1();

                return;

            }

            s = llList2String(Sits, (integer)message - 1);

            if(s != "") Anims = llListReplaceList(Anims, [s], 1, 1);

            if(CurAnimType == 1) StartAni(1, s);

            Menu5();

            return;

        } else if(DlgType == 6)

        {

            if(message == "Ende") return;

            else if(message == "Zurück")

            {

                Menu1();

                return;

            }

            s = llList2String(GroundSits, (integer)message - 1);

            if(s != "") Anims = llListReplaceList(Anims, [s], 0, 0);

            if(CurAnimType == 0) StartAni(0, s);

            Menu6();

            return;

        } else if(DlgType == 7)

        {

            if(message == "Ende") return;

            else if(message == "Zurück")

            {

                Menu1();

                return;

            } else if(message == "Stop")

            {

                if(CurAnimType == 26)

                {

                    llStopAnimation(CurAni);

                    CurAni = "";

                    CurAnimType = -1;

                    NextStand();

                }

            } else

            {

                s = llList2String(Dances, (integer)message - 1);

                if(s != "") Anims = llListReplaceList(Anims, [s], 26, 26);

                StartAni(26, s);

                Menu7();

                return;

            }

        }

    }

    control(key id, integer levels, integer edges)

    {

        if(!On) return;

        if(edges && llGetAnimation(llGetOwner()) == "Walking")

        {

            if(levels & edges & (CONTROL_BACK | CONTROL_FWD))

            {

                if(llGetListLength(Walks) > 0)

                {

                    llStopAnimation("walk");

                    llStopAnimation("female_walk");

                }

            }

            StartAni(18, llList2String(Anims, 18));

        }

    }

}

Beispiel-config:

Code:
AnimType = Sitting on Ground

GSitShy

AnimType = Sitting

sitShy1

sitshy2

AnimType = Striding

AnimType = Crouching

crouchshy

AnimType = CrouchWalking

AnimType = Soft Landing

AnimType = Standing Up

AnimType = Falling Down

AnimType = Hovering Down

HoverD

AnimType = Hovering Up

HoverU

AnimType = FlyingSlow

AnimType = Flying

FlyShy

AnimType = Hovering

Hover

Animtype = Jumping

jumP

Animtype = PreJumping

Prejump

AnimType = Running

runf

runfist

AnimType = Turning Right

TURNR

AnimType = Turning Left

TURNL

Animtype = Walking

sexywalk

walk_bis

walk 3

AnimType = Landing

LandingF

Animtype = Standing

stand1

stand2

stand2-2

stand3

stand4

stand4-4

stand6

stand7

stand8-1

stand10

standingf

stand14

stand14-1

stand17

stand17-1

AnimType = Swimming Down

AnimType = Swimming Up

AnimType = Swimming Forward

swimF

AnimType = Floating

float

Animtype = Typing

ftyping

AnimType = Dance

Butterscotch

we love you girl

weeeee

Lampenskript

Tue, 06 Nov 2012 11:32:22 +0100

Ich richte grad mein Haus ein und da hat mich bei den Lampen gestört, dass da immer massenhaft Skripte drin waren. Also hab ich mir mal ein Lampen-Skript gemacht, das für alles geeignet ist und das bei mir jetzt in alle Lampen kommt. Vielleicht kanns ja noch jemand gebrauchen.
Außerdem hat hier schon zu lange keiner mehr was geschrieben :-)

Mal ne kurze Erläuterung:
Mit dem Skript kann man eine oder mehrere Lampen steuern, per Klick und/oder automatisch bei Nacht oder Tag einschalten. Wer nur die Automatik Wünscht, löscht einfach das Event touch_start aus dem Skript raus. Per Linkset wird nur ein Skript benötigt.
Die Prims der Lampe, die leuchten sollen, benennt ihr wie es bei PRIMNAME steht, also hier "light". Der gilt immer für das gesamte Linkset, also kann man auch mehrere Lampen verlinken und braucht dann nur das eine Skript.
Der Channel ist nur dafür da, um nicht verlinkte Lampen simweit fernzusteuern, in jede Lampe muss dann das Skript rein. Mit unterschiedlichen Kanälen kann man so auch verschiedene Lampengruppen steuern. Wird das nicht benötigt, einfach nur Channel = 0 setzen.
Wenn AUTOMATIC = TRUE ist dann wird die Lampe automatisch bei Nacht eingeschaltet (oder bei Tag wenn ON_AT_NIGHT = FALSE ist, warum auch immer man das brauchen sollte). Man kann die Lampe dann aber trotzdem per Hand abschalten, sie wird dann erst wieder nächste Nacht automatisch eingeschaltet.
Es folgen die drei möglichen Prim-Eigenschaften Glow, Light und Fullbright, die kann jeder so einstellen wie er will. Die jeweils erste Konstante mit _ON am Ende gibt an, ob diese Eigenschaft verwendet werden soll oder nicht. (Wenn alle drei ausgeschaltet sind ist es aber keine Lampe mehr.)
Und zum Schluss kann mans noch einen Sound ertönen lassen wenn man die Lampe anklickt...

Edit: Sorry Zeile vergessen

Code:
// Konstanten

// Allgemeines

string  PRIMNAME = "light";                // Name der Prims die als Lampen fungieren

integer CHANNEL = -99999;                // Listenerkanal (0 wenn nicht gewünscht)

// Nachtschaltung

integer AUTOMATIC = TRUE;                // Soll automatisch eingeschaltet werden?

integer ON_AT_NIGHT = TRUE;                // Lampe an bei Nacht (wenn FALSE dann an bei Tag)

// Glühen

integer GLOW_ON = TRUE;                    // Glühen an oder nicht

float GLOW_INTENSITY = 0.5;                // Intensität des Glühens (0..1)

integer GLOW_SIDE = ALL_SIDES;            // Seite(n) fürs Glühen

// Leuchten

integer LIGHT_ON = TRUE;                // Licht an oder nicht

vector LIGHT_COLOR = <1.0, 1.0, 1.0>;    // Farbe für Licht

float LIGHT_INTENSITY = 1.0;             // Intensität des Leuchtens (0..1)

float LIGHT_RADIUS = 5.0;                // Lichtradius in m

float LIGHT_FALLOFF = 0.75;                // Abfall des Leuchtens

// Helligkeit

integer BRIGHT_ON = TRUE;                // Helligkeit an oder nicht

integer BRIGHT_SIDE = ALL_SIDES;        // Seite(n) für die Helligkeit

// Schalter-Sound

integer PLAY_SOUND = TRUE;                // Sound an oder nicht

float SOUND_VOL = 0.5;                    // Lautstärke (0..1)

string  SOUND = "bac3e333-9624-4b1a-ade2-d2b01d5960aa";    // ein Klicken

// Variablen

integer Mode;

integer On;

integer LastCheck = FALSE;

LightOn()

{

    list l = [];

    if(LIGHT_ON) l += [PRIM_POINT_LIGHT, TRUE, LIGHT_COLOR, LIGHT_INTENSITY, LIGHT_RADIUS, LIGHT_FALLOFF];

    if(GLOW_ON) l += [PRIM_GLOW, GLOW_SIDE, GLOW_INTENSITY];

    if(BRIGHT_ON) l += [PRIM_FULLBRIGHT, TRUE];

    integer i;

    integer x = llGetNumberOfPrims();

    for(i = 1; i <= x; i++) if(llGetLinkName(i) == PRIMNAME) llSetLinkPrimitiveParamsFast(i, l);

    if(CHANNEL != 0) llRegionSay(CHANNEL, (string)TRUE);

    On = TRUE;

}

LightOff()

{

    list l = [];

    if(LIGHT_ON) l += [PRIM_POINT_LIGHT, FALSE, LIGHT_COLOR, LIGHT_INTENSITY, LIGHT_RADIUS, LIGHT_FALLOFF];

    if(GLOW_ON) l += [PRIM_GLOW, GLOW_SIDE, 0.0];

    if(BRIGHT_ON) l += [PRIM_FULLBRIGHT, FALSE];

    integer i;

    integer x = llGetNumberOfPrims();

    for(i = 1; i <= x; i++) if(llGetLinkName(i) == PRIMNAME) llSetLinkPrimitiveParamsFast(i, l);

    if(CHANNEL != 0) llRegionSay(CHANNEL, (string)FALSE);

    On = FALSE;

}

Switch(integer on)

{

    if(on) LightOn(); else LightOff();

}

default {

    state_entry()

    {

        Mode = FALSE;

        On = FALSE;

        Switch(On);

        if(CHANNEL != 0) 

               {

                      llRegionSay(CHANNEL, (string)On);

                      llListen(CHANNEL, "", NULL_KEY, "");

               }

               if(AUTOMATIC) llSetTimerEvent(60.0);

    }

    touch_start(integer total_number)

    {

        if (PLAY_SOUND) llPlaySound(SOUND, SOUND_VOL);

        On = !On;

        Switch(On);

    }

    on_rez(integer start_param)

    {

        llResetScript();

    }

    timer()

    {

        vector v = llGetSunDirection();       

        if (v.z < 0.0) Mode = ON_AT_NIGHT;

        else Mode = !ON_AT_NIGHT;      

        if (Mode != LastCheck)

        {

            Switch(Mode);

            LastCheck = Mode;

        }

    }

    listen(integer channel, string name, key id, string message)

    {

        On = (integer)message;

        Switch(On);

    }

}

Scripts aus dem OSGrid Forum

Mon, 27 Dec 2010 01:34:19 +0100

Hier ein langes Posting aus dem OSGrid Forum. Alles Scripts die man wohl in OS gebrauchen kann.

http://forums.osgrid.org/viewtopic.php?f=5&t=2233

Messageboard mit message per chat

Thu, 25 Nov 2010 15:53:46 +0100

Sag es mit Worten ;D

Schreibt im Chat

/43 euremessage oder
/43 !clear um eure message zu lÃ¶schen

Code:
// Grafitti board 0.0.2 for OpenSim

// By Justin Clark-Casey (justincc)

// http://justincc.wordpress.com

// This script is available under the BSD License

string text = "";

integer LISTENING_CHANNEL = 43;

// XXX Only putting this here as well to get around OpenSim's int -> string casting oddness

string LISTENING_CHANNEL_STRING = "43";

// FIXME: Should be dynamic!

integer CHARS_WIDTH = 40;

// Add some additional graffiti

addGraffiti(string message)

{

    while (llStringLength(message) > CHARS_WIDTH)

    {

        text += "\n\n" + llGetSubString(message, 0, CHARS_WIDTH - 1);

        message = llDeleteSubString(message, 0, CHARS_WIDTH - 1);

    }

    text += "\n\n" + message;

}

// Clear the existing graffiti

clearGraffiti()

{

    text = "";

}

// Actually fires the graffiti out to the dynamic texture module

draw()

{

    //llSay(0, text);

    string drawList = "PenColour BLACK; MoveTo 40,220; FontSize 32; Text " + text + ";";

    osSetDynamicTextureData("", "vector", drawList, "1024", 0);

}

default

{

    state_entry()

    {

        llSetText(

            "Say /" + LISTENING_CHANNEL_STRING + "  to add text.\n"

            + "  Say /" + LISTENING_CHANNEL_STRING

            + " !clear to clear board",

            <0.0, 1.0, 0.0>, 1.0);

        llListen(LISTENING_CHANNEL, "", NULL_KEY, "");

        addGraffiti("Hypernauts, leave a message here");

        draw();

    }

    listen(integer channel, string name, key id, string message)

    {

        if (message == "!clear")

        {

            clearGraffiti();

        }

        else

        {

            addGraffiti(message);

        }

        draw();

    }

}

Gefunden im Reaktiongrid ;D

Teleport-Script innerhalb der Region

Sun, 21 Nov 2010 19:02:36 +0100

endlich hat die Rennerei ein Ende, seufz.....

Code:
integer CHANNEL = 42; // dialog channel

list MENU_MAIN = ["Plattform", "Villa Schepp","Grotte","Klamotten", "Haus"]; 

key lastAVkey = NULL_KEY;

string fltText = "Teleport";

vector dest ;

default

{

    state_entry()

    {

          llListen(CHANNEL, "", NULL_KEY, ""); // listen for dialog answers (from multiple users)

 llSetSitText("Teleport");

        llSetText(fltText, <1,1,1>, 1);

    }

    touch_start(integer i)

    {

       llDialog(llDetectedKey(0), "Ziele", MENU_MAIN, CHANNEL); // present dialog on click

    }

    listen(integer channel, string name, key id, string message)

     /// Menu selber ende

     {

     if (message == "Plattform") dest = <116.309013,126.735489,498.082306> ;

   if (message == "Grotte") dest =  <203.817749,33.219597,21.493137>;

 if (message == "Villa Schepp") dest = <86.953094,207.898895,21.250000>  ;

 if (message == "Klamotten") dest = <11.276321,129.932083,21.332373> ;

if (message == "Haus") dest = <51.443775,38.852882,21.336037>;

 llSitTarget(dest-llGetPos(), <0,0,0,1>);   

    }

    changed(integer change)

    {

        key currentAVkey = llAvatarOnSitTarget();

        if (currentAVkey != NULL_KEY && lastAVkey == NULL_KEY)

        {

            lastAVkey = currentAVkey;        

            if (!(llGetPermissions() & PERMISSION_TRIGGER_ANIMATION))  

                llRequestPermissions(currentAVkey,PERMISSION_TRIGGER_ANIMATION);

            llUnSit(currentAVkey);

            llStopAnimation("sit");

            llResetScript();

        }

    }

}